[TUTO] PINemHi - Score sur le FrontEnd par Flajolbass et Tcholeaway

Code:

"C:\PinCab\PINemHi\pinemhi.exe" -lr>"C:\PinCab\PINemHi\supported.txt"

Code:

"c:\PinCab\PINemHi\hiscore.bat" [?ROM?] "[GAMENAME]" "[?GameType?]"  

Code:

"C:\PinCab\PINemHi\hiscorePFX.bat" [GAMENAME]

Code:

arfm113b,afm_113b

Code:

Const cGameName = "arfm113b"

Code:

START "" "[STARTDIR]Launch\VPXSTARTER.exe" 10 10 60 “Visual Pinball Player” 3 0 5
Set NVRamPath=c:\PinCab \Visual Pinball\VPinMAME\nvram
if [?ROM?]==afm113b xcopy "%NVRamPath%\afm113b1.nv" "%NVRamPath%\afm113b.nv" /y
if [?ROM?]==arfm113b xcopy "%NVRamPath%\afm113b2.nv" "%NVRamPath%\afm113b.nv" /y

Code:

REM FIN DE CONFIGURATION
REM --------------------
REM END OF VARIABLES DECLARATION
if %1==arfm113b copy "%NVRamPath%\afm113b.nv" "%NVRamPath%\afm113b2.nv"
if %1==afm113b copy "%NVRamPath%\afm113b.nv" "%NVRamPath%\afm113b1.nv"

Code:

:NVRAM
REM Start of NVRAM processing
SET TEMPTXT=%~1
SET OUTPUT=%POPVPMedia%
if %TEMPTXT%==arfm113b SET TEMPTXT=afm113b

But final de la procédure : 

Comment ça marche? :

1. Appel à PINemHi, qui est un programme qui va "parser" les fichiers nvram (ou fpram pour FP) pour y extraire les scores et les mettre dans un fichier texte.
   
2. Ensuite, ce fichier texte va être utilisé par un autre programme, ImageMagick, qui va en fait créer une image sur base d'un fond et du texte précédemment extrait
   
3. Cette image va être déposée dans le dossier des GameInfo de PinupPOPPER, pour pouvoir être appelée via la simple pression d'un bouton dans votre sélection de tables sous PinupPOPPER 
   

Pré-Requis : 

• Télécharger PINemHi version 1.3.1 --> https://www.vpforums.org/index.php?showtopic=39956
  
• Télécharger la version portable-Q16-x86 de ImageMagick --> https://imagemagick.org/script/download.php. Actuellement il et en version ImageMagick-7.0.10-62-portable-Q16-x86.zip téléchargeable directement ICI
  
• Télécharger une image de fond pour votre image de scores. Perso, j'ai bêtement pris ce que proposait Nailbuster ICI, mais n'importe quelle image qui vous plait fera l'affaire. Renommez votre image en "chalkboard.jpg"
  
• Optionnel : Télécharger 7-Zip (normalement c'est déjà fait).
  

Préparation des dossiers : 

• Déziper le contenu du ZIP "PINemHI" où vous voulez (perso je l'ai mis à la racine de mon disque dur, donc dans c:\PINemHi)
  
• Dans ce dossier, créez les 2 sous-dossiers suivants : PNGs, Text
  
• Dans le dossier PNGs, aller déposer votre image "chalkboard.jpg"
  
• Déziper le contenu du ZIP ImageMagick où vous voulez (pero je l'ai mis à la racine de mon disque dur, donc dans c:\ImageMagick)
  

Création et modification du script highscore.bat : 

Code:

@echo off
SETLOCAL EnableDelayedExpansion

REM START OF VARIABLES DECLARATION

    REM Set the following variables based on your setup
    REM Path to PINemHI
    SET "PINemHiPath=c:\PINemHi"

    REM Path to ImageMagick
    SET "ImageMagick=c:\ImageMagick"

    REM Path to TXT files with HiScores
    SET "PINemHiHS=c:\PINemHi\Text"
    If NOT EXIST "%PINemHiHS%" (mkdir "%PINemHiHS%")

    REM Path for temporary PNGs and background image
    SET "PINemHiPNG=c:\PINemHi\PNGs"

    REM Filename of background image to be used
    SET "Background=chalkboard.jpg"

    REM Path to VPinMAME nvram files
    SET "NVRamPath=c:\Visual Pinball\VPinMAME\nvram"

    REM Path to FP nvram files
    SET "FPNVRamPath=c:\Future Pinball\fpRAM"

    REM Path to VP User files
    SET "UserPath=c:\Visual Pinball\User"

    REM Path to 7z
    SET "Zexepath=c:\ProgramFiles\7z"

    REM Folder where you want the VP high score PNGs with high scores placed (GameInfo, Topper, DMD, etc.)
    SET "POPVPMedia=c:\PinupSystem\POPMedia\Visual Pinball X\GameInfo"

    REM Folder where you want the FP high score PNGs with high scores placed (GameInfo, Topper, DMD, etc.)
    SET "POPFPMedia=c:\PinupSystem\POPMedia\Future Pinball\GameInfo"

    REM This suffix will be added to the second parameter passed (tablename) when saving high score PNGs
    SET "Suffix="

REM END OF VARIABLES DECLARATION

REM Need to change to the PINemHi folder in order for the exe to read its INI
cd "%PINemHiPath%"
REM Uncomment the next line to regenerate PINemHi supported roms DB
REM "%PINemHiPath%\pinemhi.exe" -lr>"%PINemHiPath%\supported.txt"

REM We will select the right parsing routine
SET ISTEXT=%3
if "%ISTEXT%" == "BAM" GOTO FUTURE
SET ISTEXT=%3
if "%ISTEXT%" == "UltraDMD" GOTO ULTRADMD
SET ISTEXT=%1
SET ISTEXT=%ISTEXT:~-5%
set ISTEXT=%ISTEXT:"=%
if "%ISTEXT%" == ".txt" GOTO POSTIT

GOTO NVRAM

:FUTURE
REM Start of fpram processing
SET TEMPTXT=%~2
SET OUTPUT=%POPFPMedia%
REM if there is no FP nvram file, exit
IF NOT EXIST "%FPNVRamPath%\%~2.fpram" exit
REM call PINemHi pipped to a txt file
"%PINemHiPath%\pinemhi.exe" %~2.fpram>"%PINemHiHS%\%~2.txt"
REM delete TXT files with size 0 as they are empty
for /f %%I in ("%PINemHiHS%\%~2.txt") do if %%~zI==0 del "%PINemHiHS%\%TEMPTXT%.txt"
GOTO PNG

:ULTRADMD
REM Start of ULTRADMD processing
SET TEMPTXT=%~1
SET OUTPUT=%POPVPMedia%
REM extract hiscore files from iStor
@echo High Scores>"%PINemHiHS%\%TEMPTXT%.txt"
%Zexepath%\7z.exe x -o"%PINemHiHS%" "%UserPath%\VPReg.stg" %1
REM Then parse and build TXT file similar to POSTIT
FOR /L %%G IN (1,1,4) DO (
    more "%PINemHiHS%\%1\HighScore%%GName">>"%PINemHiHS%\%TEMPTXT%.txt"
    more "%PINemHiHS%\%1\HighScore%%G">>"%PINemHiHS%\%TEMPTXT%.txt"
    echo.>>"%PINemHiHS%\%TEMPTXT%.txt"
)
REM we now clean temp files
rmdir "%PINemHiHS%\%1" /s/q
REM delete TXT files with size 0 as they are empty
for /f %%I in ("%PINemHiHS%\%TEMPTXT%.txt") do if %%~zI==0 del "%PINemHiHS%\%TEMPTXT%.txt"
GOTO PNG

:POSTIT
REM Start POSIT is file processing
SET TEMPTXT=%~1
SET TEMPTXT=%TEMPTXT:"=%
SET OUTPUT=%POPVPMedia%
REM if there is no PostIT file, exit
IF NOT EXIST "%UserPath%\%TEMPTXT%" exit
REM We read the PostIT file into an Array
set var[0]=0
set /a idx=0
for /f "usebackq delims=" %%I in ("%UserPath%\%TEMPTXT%") do (
    set "var[!idx!]=%%I"
    set /a idx += 1
    )
REM We generate a text file with the high scores table
@echo High scores:>"%PINemHiHS%\%TEMPTXT%.txt"
set /a "HSN=idx-5"
set /a "HS=idx-10"
:While
    IF %HSN% EQU %idx% GOTO EndWhile
        call echo %%var[!HSN!]%% %%var[!HS!]%%>>"%PINemHiHS%\%TEMPTXT%.txt"
        set /a HSN += 1
        set /a HS += 1
        GOTO While
:EndWhile
GOTO PNG

:NVRAM
REM Start of NVRAM processing
SET TEMPTXT=%~1
SET OUTPUT=%POPVPMedia%

REM if there is no nvram file, exit
IF NOT EXIST "%NVRamPath%\%TEMPTXT%.nv" exit
REM we will only process the nvram file if the rom is supported by PINemHi
for /F "usebackq delims=" %%A in ("%PINemHiPath%\supported.txt") do (
    if %%A==%TEMPTXT% (
        REM call PINemHi pipped to a txt file
        "%PINemHiPath%\pinemhi.exe" %TEMPTXT%.nv>"%PINemHiHS%\%TEMPTXT%.txt"
        )
    )
REM delete TXT files with size 0 as they are empty
for /f %%I in ("%PINemHiHS%\%TEMPTXT%.txt") do if %%~zI==0 del "%PINemHiHS%\%TEMPTXT%.txt"
GOTO PNG

:PNG
REM Call ImageMagick convert to create a PNG from the hiscore TXT file (note color, font and other options available)
REM Choose to size the resulting image based on the background file you use
REM if you'd like a monospaced output, add -font Courier
IF EXIST "%PINemHiHS%\%TEMPTXT%.txt" (
    type "%PINemHiHS%\%TEMPTXT%.txt" | "%ImageMagick%\convert.exe" -background none -fill yellow -pointsize 26 pango:@- -resize 570x730 "%PINemHiPNG%\%TEMPTXT%.png"
    )

REM Call ImageMagick composite to merge previous PNG with the background image, and center it
IF EXIST "%PINemHiPNG%\%TEMPTXT%.png" (
    "%ImageMagick%\composite.exe" "%PINemHiPNG%\%TEMPTXT%.png" "%PINemHiPNG%\%Background%" -gravity center "%OUTPUT%\%~2%Suffix%.png"
    REM Cleanup temp PNGs
    del "%PINemHiPNG%\%TEMPTXT%.png"
    )

REM done
exit /B

Configuration de PinUpPOPPER : 

Code:

REM Generate HiScore media file
"c:\PinemHi\hiscore.bat" [?ROM?] "[GAMENAME]" "[?GAMETYPE?]"

1. Il va falloir donner à chaque table que vous avez installé on nom de rom dans PinupPOPPER. Pour celà, allez dans le menu "GameManager" de PinupPOPPER. Cliquez sur le jeu en question, et dans le champ "rom" indiquez le nom de la ROM SANS L'EXTENSION ".ZIP". Exemple pour Pharao --> mettre pharo_l2 (et non pharo_l2.zip)
   
2. Vous allez après devoir lancer la table via PinupPOPPER. Une fois qu'elle est chargée et initialisée, vous pouvez la quitter. 
   

Troubleshooting :

• Allez voir dans le dossier PinupSystem\POPMedia\Visual Pinball X\GameInfo si l'image est bien présente. Si non, passez au point suivant. Si oui, il y a un soucis dans l'appel GameInfo de l'image. Assurez-vous d'avoir assigné le bouton correctement. Si vous êtes sûr, de votre coup, allez dans PinupPOPPER setup --> MediaManager. Sélectionner la table Pharo. Regardez le média "GameInfo". S'il est en jaune, c'est que l'association entre le jeu et l'image ne s'est pas faite. Là, vous pouvez faire un "drag & drop" de l'image de scores générée, le média passera en vert. Théoriquement maintenant ça devrait l'afficher dans PinupPOPPER
  
• Si l'image n'est pas générée, allez dans le dossier PINemHi\Text. Vous devriez y voir un fichier texte pharo_l2.txt. S'il n'est pas présent, allez au point suivant. S'il est présent, et que vous n'avez donc pas de fichier image, c'est que la génération de l'image ne s'est pas bien passée. J'ai moi même encore le cas avec certaines tables voir "section Limitations actuelles"). Mais je l'ai eu aussi, et il se fait que j'avais mal adressé le dossier "ImageMagick".  A creuser donc
  
• Si le fichier texte n'est pas généré, il se peut que la table n'est pas gérée par PINemHi (425 tables sont actuellement supportées sur VPX, et sa dernière release date de 2018). Il se peut aussi que vous ayez commis un soucis d'adressage dans le fichier hiscore.bat ou dans le nom de la rom encodée dans GameManager de PinupPOPPER
  

Limitations actuelles : 

• AC/DC, Metallica, SpiderMan et certaines d'autre >2010
  
• toutes les tables UltraDMD --> Consultez le tuto de Nailbuster référencé ci-dessus pour voir les subtilités
  

Remerciements : 

flajolbass a écrit:

Salut à tous, 
Oui je pense qu'une fusion de tuto sera au top !!

ced a écrit:

edit: pour la table acdc il parait que ça ne fonctionne pas , c'est précisé dans le tuto

benben a écrit:

ced a écrit:

edit: pour la table acdc il parait que ça ne fonctionne pas , c'est précisé dans le tuto

En fait, ça fonctionne très bien pour la rom acd_168, j'arrive à extraire les scores et tout.

C'est au niveau de la création du png que ça bloque

• Avant le code du fichier bat, tu le nommes "highscore.bat". Tu le nommes ensuite "hiscore.bat" dans la section Close de Pinup Popper. Il faut que les 2 correspondent.
  

• Quand on va vouloir gérer autre chose que des tables VPX SS, il va falloir remplir la zone "Game Type" en + de la rom dans le Game Manager pour que PINemHI les traite correctement.
  

• Pour que PINemHI lance le parse d'une ram, il vérifie d'abord sa compatibilité avec une liste. Le fichier "supported.txt" doit exister dans le répertoire PINemHI. Pour cela, deux options :
  

1. Dé commenter la ligne "%PINemHiPath%\pinemhi.exe" -lr>"%PINemHiPath%\supported.txt" dans le .bat
   
2. Sous DOS, dans le répertoire PINemHI, taper en ligne de commande : pinemhi -lr> supported.txt
   

Code:

GRAND CHAMPION
SLL    7.500.000.000

HIGHEST SCORES
1) BRE    7.000.000.000
2) LFS    6.500.000.000
3) RCF    6.000.000.000
4) DTW    5.500.000.000

MARTIAN CHAMPION
LFS - 20
MARTIANS DESTROYED

RULER OF THE UNIVERSE
TEX
INAUGURATED
16 NOV, 2019 9:52 PM

BUY-IN HIGHEST SCORES
1) DWF    5.000.000.000
2) ASR    4.500.000.000
3) BCM    4.000.000.000
4) MOO    3.500.000.000